@echo off
set CURDIR=%~dp0

set ARMCC_PATH=
set PATH_TMP=
@for %%i in (armcc.exe) do (
	@if not "%%~$PATH:i"=="" ( 
		set PATH_TMP=%%~$PATH:i
		SETLOCAL ENABLEDELAYEDEXPANSION
		for /f "delims=" %%i in ('armcc --vsn') do (set ret=!ret!%%i;)
		(echo !ret! | findstr /C:"Software supplied by" >nul) && (echo !ret! | findstr /C:"ARM Compiler 5" >nul) && (ENDLOCAL & goto SITE1)
		ENDLOCAL
		goto SITE2
	) else (
		goto SITE2
	)
)
:SITE1
set PATH_TMP=%PATH_TMP:\armcc.exe=%
set ARMCC_PATH=%PATH_TMP%

:SITE2
set COMPILE_ENV_SET_FLAG=
set PATH=%SystemRoot%;%SystemRoot%\system32;

if "%QUECTEL_COMPILE_TOOLS_V1%"=="" (
    set QUECTEL_COMPILE_TOOLS_V1=%CURDIR%\..\..\ql-cross-tool\win32\owtoolchain
)
if "%ARMCC_PATH%"=="" (
    set ARMCC_PATH=%QUECTEL_COMPILE_TOOLS_V1%\ARM_Compiler_5\bin
    set ARMLMD_LICENSE_FILE=%QUECTEL_COMPILE_TOOLS_V1%\license.dat
)
set COMPILE_TOOLS_PATH=%PATH%;%ARMCC_PATH%;%QUECTEL_COMPILE_TOOLS_V1%;%QUECTEL_COMPILE_TOOLS_V1%\Perl\site\bin;%QUECTEL_COMPILE_TOOLS_V1%\Perl\bin;%QUECTEL_COMPILE_TOOLS_V1%\Gnumake;
if "%COMPILE_ENV_SET_FLAG%"==""  echo --------------set compile tools path------------------- && set PATH=%COMPILE_TOOLS_PATH% && set COMPILE_ENV_SET_FLAG=done
echo PATH:
echo %PATH%
echo -------------------------------------------------------
echo.


::::::::::::::::::::::::::::  功能选择  ::::::::::::::::::::::::::::
:: LCD功能, 可选 1.NO_LCD 2.USE_LCD
set LCD_TYPE=NO_LCD

:: 平台选择, 可选 1.CRANEM_SINGLESIM(1603) 2.CRANEL(CRANEL系列包含1606、1602、1605、1607、1609)
set PLATFORM=CRANEL
:: FOTA类型, 有如下类型, 需要选择合适的方案
::		空							// 带UPDATER的MINI FOTA
::		SPINOR_SUPPORT				// 带UPDATER的MINI FOTA, 支持NOR FLASH
::		NOUPDT						// 不带UPDATER的MINI FOTA
::		NOUPDT_SPINOR_SUPPORT		// 不带UPDATER的MINI FOTA, 支持NOR FLASH
::		FBF							// FBF FOTA
::		SECFOTA_FBF					// FBF FOTA, 支持安全FOTA
::		FBF_SPINOR_SUPPORT			// FBF FOTA, 支持NOR FLASH
::		SECFOTA_FBF_SPINOR_SUPPORT	// FBF FOTA, 支持NOR FLASH, 支持安全FOTA
::		FBF_SPINAND_SUPPORT			// FBF FOTA, 支持NAND FLASH
::		SECFOTA_FBF_SPINAND_SUPPORT	// FBF FOTA, 支持NAND FLASH, 支持安全FOTA, 空间太大, 不支持
set FOTA_FUNC=SPINOR_SUPPORT
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

set FOTA_TYPE=ASRDM_%PLATFORM%_%FOTA_FUNC%

pushd build\
@call m_tee build.bat
popd
pause